let () =
  Avutil.Log.set_level `Debug;
  Avutil.Log.set_callback print_string;

  let format = Option.get (Av.Format.find_input_format "v4l2") in
  let src = Av.open_input ~format "/dev/video0" in

  let () =
    print_endline "Available outputs:";
    List.iter
      (fun f -> print_endline ("- " ^ Av.Format.get_output_name f))
      (Avdevice.get_video_output_formats ())
  in

  let video, video_frame =
    try
      let video_idx, video_src, _ = Av.find_best_video_stream src in
      let video_dst = Avdevice.open_video_output "sdl2" in
      (Some (video_idx, video_dst), [video_src])
    with Avutil.Error _ -> (None, [])
  in

  let rec f () =
    match (Av.read_input ~video_frame src, video) with
      | `Video_frame (i, frame), Some (idx, dst) when i = idx ->
          Av.write_video_frame dst frame;
          f ()
      | exception Avutil.Error `Eof -> ()
      | _ -> f ()
  in
  f ();
  Av.close src;
  let () = match video with Some (_, dst) -> Av.close dst | None -> () in
  Gc.full_major ();
  Gc.full_major ()
