// names may be a series of files in src, not a wildcard.
// if it's empty then all files in src are used.
// the files are gzipped and logged in dest.
// src and dest do not have to end in /

void logZip(string src, string names, string dest)
{
    list files;
    int idx;
    string file;

    chdir(g_cwd);

    md(dest);
    dest += "/";

    if (src != "")
    {
        if (listlen(makelist(O_DIR, src)) == 0)
        {
            printf("Warning: ", src, " not found: can't install ", src, names,
                    " at ", dest, "\n");
            return;
        }
        chdir(src);
    }

    if (names == "")
        files = makelist("*");
    else
        files = strtok(names, " ");

    for (idx = listlen(files); idx--; )
    {
        file = files[idx];
        run("gzip -n -9 < " + file + " > " + file + ".gz");
    }

    run("tar cf - *.gz | (cd " + g_cwd + "; cd " + dest + "; tar xf -)");

    run("rm *.gz");
}



