#REGTEST_TYPE=devel

varnishtest "Test the ssl_s_* sample fetches"
#REQUIRE_VERSION=2.2
#REQUIRE_OPTIONS=OPENSSL
feature ignore_unknown_macro

server s1 -repeat 3 {
    rxreq
    txresp
} -start

haproxy h1 -conf {
    global
        tune.ssl.default-dh-param 2048
        tune.ssl.capture-buffer-size 1
        crt-base ${testdir}
        stats socket "${tmpdir}/h1/stats" level admin

    defaults
        mode http
        option httplog
        log stderr local0 debug err
        option logasap
        timeout connect "${HAPROXY_TEST_TIMEOUT-5s}"
        timeout client  "${HAPROXY_TEST_TIMEOUT-5s}"
        timeout server  "${HAPROXY_TEST_TIMEOUT-5s}"


    listen clear-lst
        bind "fd@${clearlst}"
        balance roundrobin
        http-response add-header x-ssl-sha1 %[ssl_s_sha1,hex]
        http-response add-header x-ssl-notafter %[ssl_s_notafter]
        http-response add-header x-ssl-notbefore %[ssl_s_notbefore]
        http-response add-header x-ssl-sig_alg %[ssl_s_sig_alg]
        http-response add-header x-ssl-i_dn %[ssl_s_i_dn]
        http-response add-header x-ssl-s_dn %[ssl_s_s_dn]
        http-response add-header x-ssl-s_serial %[ssl_s_serial,hex]
        http-response add-header x-ssl-key_alg %[ssl_s_key_alg]
        http-response add-header x-ssl-der %[ssl_s_der,hex]
        http-response add-header x-ssl-chain-der %[ssl_s_chain_der,hex]
        http-response add-header x-ssl-version %[ssl_s_version]

        server s1 "${tmpdir}/ssl.sock" ssl verify none sni str(www.test1.com)

    listen ssl-lst
        mode http

        bind "${tmpdir}/ssl.sock" ssl strict-sni crt-list ${testdir}/localhost.crt-list

        server s1 ${s1_addr}:${s1_port}
} -start


client c1 -connect ${h1_clearlst_sock} {
    txreq
    rxresp
    expect resp.status == 200
    expect resp.http.x-ssl-sha1 == "DF3B6E847A7BF83DFAAFCFEC65EE9BC36230D3EA"
    expect resp.http.x-ssl-notafter == "330917162600Z"
    expect resp.http.x-ssl-notbefore == "230920162600Z"
    expect resp.http.x-ssl-sig_alg == "RSA-SHA256"
    expect resp.http.x-ssl-i_dn == "/C=FR/L=Paris/O=HAProxy Technologies/CN=HAProxy Test Intermediate CA"
    expect resp.http.x-ssl-s_dn  == "/C=FR/L=Paris/O=test1/CN=www.test1.com"
    expect resp.http.x-ssl-s_serial == "45B6C777A017159A19126340C1053521B91E123B"
    expect resp.http.x-ssl-key_alg == "rsaEncryption"
    expect resp.http.x-ssl-version == "3"
    expect resp.http.x-ssl-der ~ 308203C7308202AFA003020102021445B6C777.*65AD7F4469DB9C8581EE260ABCB727AEF8A7C3ADA
    expect resp.http.x-ssl-chain-der ~ 308203C7308202AFA003020102021445B6C777.*D457A8C66AECA6408FF5C1A3EDBFF2888D7CED
} -run


